***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Apr 12, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt B6S DC+ AC1 AC2 DC-
.param
+vc0 = 3.403e-8		vc1 = 9.912e-11		vc2 = 1.025e-14	
+tc1 = 7.211e-2		tc2 = 3.801e-2	
g12 DC+ AC1 value={(vc0+vc1*v(DC+,AC1)+vc2*v(DC+,AC1)*v(DC+,AC1))*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))}
d12 AC1 DC+ diode
g13 DC+ AC2 value={(vc0+vc1*v(DC+,AC2)+vc2*v(DC+,AC2)*v(DC+,AC2))*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))}
d13 AC2 DC+ diode
g24 AC1 DC- value={(vc0+vc1*v(AC1,DC-)+vc2*v(AC1,DC-)*v(AC1,DC-))*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))}
d24 DC- AC1 diode
g34 AC2 DC- value={(vc0+vc1*v(AC2,DC-)+vc2*v(AC2,DC-)*v(AC2,DC-))*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))}
d34 DC- AC2 diode
.model diode d
***** flag parameter ***
+level = 1                     
***** dc model parameter ***
+ is = 2.270e-9		   n = 1.755		  rs = 4.196e-2	
+ibv = 0.1e-3		 nbv = 1			  bv = 660
***** capacitance parameter ***
+cjo = 1.935e-11		   m = 2.773e-1		  vj = 3.091e-1
+ fc = 0.5
***** temperature coefficient ***
+tnom = 25			  eg = 1.12			 xti = 3
+trs1 = 1.031e-3		trs2 = -2.341e-6			
.ends B6S
*$
